#!/bin/csh -f
#
# installation program---formerly the makefile script "make_irsim"
#

if( $?CAD_HOME == 1 ) then
	echo 'Installing in CAD_HOME='$CAD_HOME 'instead of ~cad'
	set cad_dir = $CAD_HOME
else
	echo 'Installing in ~cad'
	set cad_dir = `echo ~cad`
	if( $status != 0 ) then
	   echo 'There is no user "cad" and no $CAD_HOME.'
	   echo -n 'Where do you want to install? [/usr/local] '
	   set cad_dir = $<
	   if ( $cad_dir == "") then
	      set cad_dir = /usr/local
	   endif
	endif
endif


if( ! -d $cad_dir ) then
	echo 'Install directory does not exist:' $cad_dir
	exit 1
endif
if( ! -w $cad_dir ) then
	echo 'Install directory is not writeable:' $cad_dir
	exit 1
endif

set man_dir = $cad_dir/man
set bin_dir = $cad_dir/bin
set doc_dir = $cad_dir/doc
set lib_dir = $cad_dir/lib
set irsim_lib_dir = $cad_dir/lib/irsim

if( ! -d $bin_dir ) mkdir $bin_dir
rm -f $bin_dir/irsim
cp src/irsim/irsim $bin_dir
chmod 555 $bin_dir/irsim

rm -f $bin_dir/anXhelper
cp src/ana11/anXhelper $bin_dir
chmod 555 $bin_dir/irsim

if( ! -d $man_dir ) mkdir $man_dir
foreach mp ( man/*.? )
        set ext = $mp:e
        set nm = $mp:t
        if( ! -d $man_dir/man$ext ) mkdir $man_dir/man$ext
	rm -f $man_dir/man$ext/$nm
        cp $mp $man_dir/man$ext/$nm
        chmod 444 $man_dir/man$ext/$nm
end

if( ! -d $lib_dir ) mkdir $lib_dir
if( ! -d $irsim_lib_dir ) mkdir $irsim_lib_dir

foreach pf ( lib/*.prm )
	if ( -f $irsim_lib_dir/${pf:t} ) then
		rm $irsim_lib_dir/${pf:t}
	endif
	cp $pf $irsim_lib_dir
	chmod 444 $irsim_lib_dir/${pf:t}
end

# exit if there's no cad/doc directory

if( ! -d $doc_dir ) exit 0

if( ! -d $doc_dir/irsim ) mkdir $doc_dir/irsim

foreach d ( man/*.doc )
	if ( -f $doc_dir/irsim/${d:t} ) then
		rm $doc_dir/irsim/${d:t}
	endif
        cp $d $doc_dir/irsim
	chmod 444 $doc_dir/irsim/${d:t}
end
